rope.pl 4.7 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173
  1. #!/usr/bin/perl
  2. use strict;
  3. use warnings;
  4. use IO::Select;
  5. use File::Temp qw( tempfile );
  6. # Local modules
  7. use Cwd qw(abs_path);
  8. use File::Basename qw(dirname);
  9. use lib dirname(abs_path($0));
  10. use DMX;
  11. # User config
  12. my %DIM = (
  13. 'OFF' => [
  14. { 'channel' => 0, 'value' => 0, 'time' => 60000 }
  15. ],
  16. 'PLAY' => [
  17. { 'channel' => 1, 'value' => 64, 'time' => 500 },
  18. { 'channel' => 2, 'value' => 32, 'time' => 500 },
  19. { 'channel' => 3, 'value' => 80, 'time' => 2500 },
  20. { 'channel' => 5, 'value' => 64, 'time' => 500 },
  21. { 'channel' => 6, 'value' => 36, 'time' => 500 },
  22. { 'channel' => 7, 'value' => 32, 'time' => 500 },
  23. { 'channel' => 8, 'value' => 16, 'time' => 500 },
  24. { 'channel' => 9, 'value' => 16, 'time' => 500 },
  25. ],
  26. 'PLAY_HIGH' => [
  27. { 'channel' => 1, 'value' => 255, 'time' => 500 },
  28. { 'channel' => 2, 'value' => 128, 'time' => 500 },
  29. { 'channel' => 3, 'value' => 192, 'time' => 1500 },
  30. { 'channel' => 5, 'value' => 128, 'time' => 500 },
  31. { 'channel' => 6, 'value' => 36, 'time' => 500 },
  32. { 'channel' => 7, 'value' => 128, 'time' => 500 },
  33. { 'channel' => 8, 'value' => 16, 'time' => 500 },
  34. { 'channel' => 9, 'value' => 96, 'time' => 500 },
  35. ],
  36. 'PAUSE' => [
  37. { 'channel' => 1, 'value' => 255, 'time' => 1000 },
  38. { 'channel' => 2, 'value' => 192, 'time' => 10000 },
  39. { 'channel' => 3, 'value' => 192, 'time' => 5000 },
  40. { 'channel' => 5, 'value' => 255, 'time' => 1000 },
  41. { 'channel' => 6, 'value' => 104, 'time' => 6000, 'delay' => 3000 },
  42. { 'channel' => 7, 'value' => 192, 'time' => 10000 },
  43. { 'channel' => 8, 'value' => 96, 'time' => 6000, 'delay' => 6000 },
  44. { 'channel' => 9, 'value' => 96, 'time' => 6000, 'delay' => 3000 },
  45. ],
  46. 'MOTION' => [
  47. { 'channel' => 1, 'value' => 255, 'time' => 1000 },
  48. { 'channel' => 2, 'value' => 192, 'time' => 1000 },
  49. { 'channel' => 3, 'value' => 192, 'time' => 1000 },
  50. { 'channel' => 5, 'value' => 192, 'time' => 1000 },
  51. { 'channel' => 6, 'value' => 104, 'time' => 1000 },
  52. { 'channel' => 7, 'value' => 192, 'time' => 1000 },
  53. { 'channel' => 8, 'value' => 96, 'time' => 2000 },
  54. { 'channel' => 9, 'value' => 96, 'time' => 1500 },
  55. ],
  56. );
  57. # App config
  58. my $TEMP_DIR = `getconf DARWIN_USER_TEMP_DIR`;
  59. chomp($TEMP_DIR);
  60. my $DATA_DIR = $TEMP_DIR . 'plexMonitor/';
  61. my $STATE_SOCK = $DATA_DIR . 'ROPE.socket';
  62. my $PUSH_TIMEOUT = 20;
  63. my $PULL_TIMEOUT = $PUSH_TIMEOUT * 3;
  64. # Debug
  65. my $DEBUG = 0;
  66. if ($ENV{'DEBUG'}) {
  67. $DEBUG = 1;
  68. }
  69. # Command-line arguments
  70. my ($DELAY) = @ARGV;
  71. if (!$DELAY) {
  72. $DELAY = $PULL_TIMEOUT / 2;
  73. }
  74. # Sanity check
  75. if (!-d $DATA_DIR) {
  76. die("Bad config\n");
  77. }
  78. # Sockets
  79. my $select = DMX::stateSocket($STATE_SOCK);
  80. DMX::stateSubscribe($STATE_SOCK);
  81. my $dmx_fh = DMX::dmxSock();
  82. # State
  83. my $state = 'INIT';
  84. my $stateLast = $state;
  85. my %exists = ();
  86. my $pushLast = 0;
  87. my $pullLast = time();
  88. # Always force lights out at launch
  89. DMX::dim({ 'channel' => 0, 'value' => 0, 'time' => 0 });
  90. # Loop forever
  91. while (1) {
  92. # Set anywhere to force an update this cycle
  93. my $forceUpdate = 0;
  94. # State is calculated; use newState to gather data
  95. my $newState = $state;
  96. # Wait for state updates
  97. my @ready_clients = $select->can_read($DELAY);
  98. foreach my $fh (@ready_clients) {
  99. # Read the global state
  100. my $cmdState = DMX::parseState($fh, \%exists);
  101. # Only accept valid states
  102. if (!defined($DIM{$cmdState})) {
  103. print STDERR 'Invalid state: ' . $cmdState . "\n";
  104. next;
  105. }
  106. # Propogate the most recent command state
  107. $newState = $cmdState;
  108. $pullLast = time();
  109. }
  110. # Calculate the new state
  111. $stateLast = $state;
  112. if ($exists{'LIGHTS'}) {
  113. if ($newState eq 'PLAY') {
  114. $newState = 'PLAY_HIGH';
  115. }
  116. } else {
  117. if ($newState eq 'PLAY_HIGH') {
  118. $newState = 'PLAY';
  119. }
  120. }
  121. $state = $newState;
  122. # Force updates on a periodic basis
  123. if (time() - $pushLast > $PUSH_TIMEOUT) {
  124. $forceUpdate = 1;
  125. }
  126. # Die if we don't see regular updates
  127. if (time() - $pullLast > $PULL_TIMEOUT) {
  128. die('No update on state socket in past ' . $PULL_TIMEOUT . " seconds. Exiting...\n");
  129. }
  130. # Update the lighting
  131. if ($forceUpdate || $stateLast ne $state) {
  132. if ($DEBUG) {
  133. print STDERR 'State: ' . $stateLast . ' => ' . $state . "\n";
  134. DMX::printDataset($DIM{$state});
  135. }
  136. # Send the dim command
  137. my @values = ();
  138. foreach my $data (@{ $DIM{$state} }) {
  139. DMX::dim($data);
  140. push(@values, $data->{'channel'} . ' => ' . $data->{'value'} . ' @ ' . $data->{'time'});
  141. }
  142. # Save the state and value to disk
  143. my ($fh, $tmp) = tempfile($DATA_DIR . 'ROPE.XXXXXXXX', 'UNLINK' => 0);
  144. print $fh 'State: ' . $state . "\n" . join("\n", @values) . "\n";
  145. close($fh);
  146. rename($tmp, $DATA_DIR . 'ROPE');
  147. # Update the push time
  148. $pushLast = time();
  149. }
  150. }