leds.pl 8.4 KB

123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193194195196197198199200201202203204205206207208209210211212213214215216217218219220221222223224225226227228229230231232233234235236237238239240241242243244245246247248249250251252253254255256257258259260261262263264265266267268269270271272273274275276277278279280281282283284285286287288289290291292293294295296297298299300301302303304305306307308309310311312313314315316317318319320321322323324325326327328329330331332333334335336337338339340341342343344345346347348349350351352353354355356357358359360361362363364365366367368369370371372373374375376377378379380381382383384385386387388389390391392393394395396397398399400
  1. #!/usr/bin/perl
  2. use strict;
  3. use warnings;
  4. use POSIX;
  5. use File::Touch;
  6. use Math::Random;
  7. use Time::HiRes qw( usleep );
  8. # Local modules
  9. use Cwd qw(abs_path);
  10. use File::Basename qw(dirname);
  11. use lib dirname(abs_path($0));
  12. use DMX;
  13. # Prototypes
  14. sub red_alert();
  15. sub rave();
  16. sub rave_loop();
  17. # Effects states
  18. my %EFFECTS = (
  19. 'RED_ALERT' => \&red_alert,
  20. 'RAVE' => \&rave,
  21. );
  22. # User config
  23. my $COLOR_TIMEOUT = 30;
  24. my $COLOR_TIME_MIN = int($COLOR_TIMEOUT / 2);
  25. my %COLOR_VAR = (
  26. 'PLAY' => 0.50,
  27. 'PLAY_HIGH' => 0.50,
  28. 'PAUSE' => 0.65,
  29. 'MOTION' => 0.15,
  30. );
  31. my %DIM = (
  32. 'OFF' => [
  33. # Handled by rope.pl
  34. ],
  35. 'PLAY' => [
  36. { 'channel' => 13, 'value' => 10, 'time' => 500 },
  37. { 'channel' => 14, 'value' => 10, 'time' => 500 },
  38. { 'channel' => 15, 'value' => 8, 'time' => 500 },
  39. ],
  40. 'PLAY_HIGH' => [
  41. { 'channel' => 13, 'value' => 64, 'time' => 1000, 'delay' => 3000 },
  42. { 'channel' => 14, 'value' => 64, 'time' => 1000, 'delay' => 1500 },
  43. { 'channel' => 15, 'value' => 64, 'time' => 1000, 'delay' => 0 },
  44. ],
  45. 'PAUSE' => [
  46. { 'channel' => 13, 'value' => 96, 'time' => 3000, 'delay' => 3000 },
  47. { 'channel' => 14, 'value' => 96, 'time' => 3000, 'delay' => 0 },
  48. { 'channel' => 15, 'value' => 96, 'time' => 3000, 'delay' => 7000 },
  49. ],
  50. 'MOTION' => [
  51. { 'channel' => 13, 'value' => 144, 'time' => 1000 },
  52. { 'channel' => 14, 'value' => 144, 'time' => 1000 },
  53. { 'channel' => 15, 'value' => 144, 'time' => 1000 },
  54. ],
  55. );
  56. # App config
  57. my $TEMP_DIR = `getconf DARWIN_USER_TEMP_DIR`;
  58. chomp($TEMP_DIR);
  59. my $DATA_DIR = $TEMP_DIR . 'plexMonitor/';
  60. my $OUTPUT_FILE = $DATA_DIR . 'LED';
  61. my $STATE_SOCK = $OUTPUT_FILE . '.socket';
  62. my $RAVE_FILE = $DATA_DIR . 'RAVE';
  63. my $PUSH_TIMEOUT = 20;
  64. my $PULL_TIMEOUT = 60;
  65. # Reset the push timeout if the color timeout is longer
  66. if ($PUSH_TIMEOUT < $COLOR_TIMEOUT) {
  67. $PUSH_TIMEOUT = $COLOR_TIMEOUT;
  68. }
  69. # Debug
  70. my $DEBUG = 0;
  71. if ($ENV{'DEBUG'}) {
  72. $DEBUG = 1;
  73. }
  74. # Command-line arguments
  75. my ($DELAY) = @ARGV;
  76. if (!$DELAY) {
  77. $DELAY = $PULL_TIMEOUT / 2;
  78. if ($DELAY > $COLOR_TIMEOUT / 2) {
  79. $DELAY = $COLOR_TIMEOUT / 2;
  80. }
  81. }
  82. # Sanity check
  83. if (!-d $DATA_DIR) {
  84. die("Bad config\n");
  85. }
  86. # Construct a list of valid states
  87. my %VALID = ();
  88. foreach my $key (keys(%DIM)) {
  89. $VALID{$key} = 1;
  90. }
  91. foreach my $key (keys(%EFFECTS)) {
  92. $VALID{$key} = 1;
  93. }
  94. $VALID{'STOP'} = 1;
  95. # Sockets
  96. DMX::stateSocket($STATE_SOCK);
  97. DMX::stateSubscribe($STATE_SOCK);
  98. # State
  99. my $state = 'OFF';
  100. my $stateLast = $state;
  101. my %exists = ();
  102. my %existsLast = %exists;
  103. my $pushLast = 0;
  104. my $pullLast = time();
  105. my $update = 0;
  106. my @COLOR = ();
  107. my $colorChange = time();
  108. my $PID = undef();
  109. my $EFFECT = undef();
  110. # Always force lights out at launch
  111. DMX::dim({ 'channel' => 13, 'value' => 0, 'time' => 0 });
  112. DMX::dim({ 'channel' => 14, 'value' => 0, 'time' => 0 });
  113. DMX::dim({ 'channel' => 15, 'value' => 0, 'time' => 0 });
  114. # Loop forever
  115. while (1) {
  116. # Record the last state/exists data for diffs/resets
  117. $stateLast = $state;
  118. %existsLast = %exists;
  119. # State is calculated; use newState to gather data
  120. my $newState = $state;
  121. # Reduce the select delay when we're processing background effects
  122. # We don't want to hang waiting for event updates
  123. my $delay = $DELAY;
  124. if (defined($PID)) {
  125. $delay = 0.01;
  126. }
  127. # Wait for state updates
  128. my $cmdState = DMX::readState($delay, \%exists, \%VALID);
  129. if (defined($cmdState)) {
  130. $newState = $cmdState;
  131. $pullLast = time();
  132. }
  133. # Handle "STOP" commands
  134. if ($newState eq 'STOP') {
  135. if (defined($PID)) {
  136. if ($DEBUG) {
  137. print STDERR "Ending background processing\n";
  138. }
  139. kill(SIGTERM, $PID);
  140. }
  141. $newState = $state;
  142. $update = 1;
  143. }
  144. # Reap zombie children
  145. if (defined($PID)) {
  146. my $kid = waitpid($PID, WNOHANG);
  147. if ($kid > 0) {
  148. if ($DEBUG) {
  149. print STDERR 'Reaped child: ' . $PID . "\n";
  150. }
  151. $PID = undef();
  152. $EFFECT = undef();
  153. if (-e $RAVE_FILE) {
  154. unlink($RAVE_FILE);
  155. }
  156. $update = 1;
  157. }
  158. }
  159. # Continue special processing
  160. if (defined($EFFECT)) {
  161. $EFFECT->();
  162. next;
  163. }
  164. # Special handling for effects states
  165. if (defined($EFFECTS{$newState})) {
  166. # Dispatch the handler
  167. # Optionally skip the rest of this loop
  168. if($EFFECTS{$newState}->()) {
  169. next;
  170. }
  171. # Force an update back to the original state
  172. $newState = $stateLast;
  173. %exists = %existsLast;
  174. @COLOR = ();
  175. $colorChange = time() + $COLOR_TIME_MIN;
  176. $update = 1;
  177. }
  178. # Calculate the new state
  179. if ($exists{'LIGHTS'}) {
  180. if ($newState eq 'PLAY') {
  181. $newState = 'PLAY_HIGH';
  182. }
  183. } else {
  184. if ($newState eq 'PLAY_HIGH') {
  185. $newState = 'PLAY';
  186. }
  187. }
  188. $state = $newState;
  189. # Color changes
  190. if ($COLOR_VAR{$state} && time() - $colorChange > $COLOR_TIMEOUT) {
  191. @COLOR = ();
  192. # Grab the default (white) data
  193. my $lums = 0;
  194. foreach my $data (@{ $DIM{$state} }) {
  195. $lums += $data->{'value'};
  196. }
  197. my $numChans = scalar(@{ $DIM{$state} });
  198. my $max = $lums / $numChans;
  199. # Pick the change interval
  200. my $time = int((rand($COLOR_TIMEOUT - $COLOR_TIME_MIN) + $COLOR_TIME_MIN) * 1000);
  201. # Assign each channel
  202. my @vals = random_normal($numChans, $max, $max * $COLOR_VAR{$state});
  203. foreach my $data (@{ $DIM{$state} }) {
  204. my $color = pop(@vals);
  205. push(@COLOR, { 'channel' => $data->{'channel'}, 'value' => $color, 'time' => $time });
  206. }
  207. # Update
  208. $update = 1;
  209. $colorChange = time();
  210. if ($DEBUG) {
  211. print STDERR "New color\n";
  212. }
  213. }
  214. # Force updates on a periodic basis
  215. if (time() - $pushLast > $PUSH_TIMEOUT) {
  216. $update = 1;
  217. }
  218. # Die if we don't see regular updates
  219. if (time() - $pullLast > $PULL_TIMEOUT) {
  220. die('No update on state socket in past ' . $PULL_TIMEOUT . " seconds. Exiting...\n");
  221. }
  222. # Force updates on any state change
  223. if ($stateLast ne $state) {
  224. if ($DEBUG) {
  225. print STDERR 'State change: ' . $stateLast . ' => ' . $state . "\n";
  226. }
  227. $update = 1;
  228. # Reset the color change sequence, so we always spend 1 cycle at white
  229. @COLOR = ();
  230. $colorChange = time() + $COLOR_TIME_MIN;
  231. }
  232. # Update the lighting
  233. if ($update) {
  234. # Select a data set (color or standard)
  235. my @data_set = ();
  236. my $local_state = $state;
  237. if (scalar(@COLOR)) {
  238. @data_set = @COLOR;
  239. $local_state .= ' (Color)';
  240. } else {
  241. @data_set = @{ $DIM{$state} };
  242. }
  243. # Update
  244. DMX::applyDataset(\@data_set, $local_state, $OUTPUT_FILE);
  245. # Update the push time
  246. $pushLast = time();
  247. # Clear the update flag
  248. $update = 0;
  249. # Clear the RAVE file, just in case
  250. if (-e $RAVE_FILE) {
  251. unlink($RAVE_FILE);
  252. die("Cleared orphan RAVE file\n");
  253. }
  254. }
  255. }
  256. # ======================================
  257. # Effects routines
  258. # These are blocking, so be careful
  259. # ======================================
  260. sub red_alert() {
  261. if ($DEBUG) {
  262. print STDERR "red_alert()\n";
  263. }
  264. my $ramp = 450;
  265. my @sound = ('afplay', '/mnt/media/Sounds/DMX/Red Alert.mp3');
  266. my $sleep = $ramp;
  267. my @other = ();
  268. push(@other, { 'channel' => 13, 'value' => 0, 'time' => 0 });
  269. push(@other, { 'channel' => 15, 'value' => 0, 'time' => 0 });
  270. foreach my $data (@other) {
  271. DMX::dim($data);
  272. }
  273. my %high = ('channel' => 14, 'value' => 255, 'time' => $ramp);
  274. my %low = %high;
  275. $low{'value'} = 64;
  276. DMX::dim(\%high);
  277. system(@sound);
  278. DMX::dim(\%low);
  279. usleep($sleep * 1000);
  280. DMX::dim(\%high);
  281. system(@sound);
  282. DMX::dim(\%low);
  283. usleep($sleep * 1000);
  284. DMX::dim(\%high);
  285. system(@sound);
  286. DMX::dim(\%low);
  287. usleep($sleep * 1000);
  288. }
  289. sub rave() {
  290. if ($DEBUG) {
  291. print STDERR "rave()\n";
  292. }
  293. my @sound = ('afplay', '/mnt/media/Sounds/DMX/Rave.mp3');
  294. # Play the sound in a child (i.e. in the background)
  295. $PID = fork();
  296. if (defined($PID) && $PID == 0) {
  297. exec(@sound)
  298. or die('Unable to play sound: ' . join(' ', @sound) . "\n");
  299. }
  300. # Setup our loop handler
  301. $EFFECT = \&rave_loop;
  302. # Initiate the RAVE state
  303. touch($RAVE_FILE);
  304. # Do not pass GO, do not collect $200
  305. return 1;
  306. }
  307. sub rave_loop() {
  308. if ($DEBUG) {
  309. print STDERR "rave_loop()\n";
  310. }
  311. my $max_dur = 500;
  312. my $max_val = 255;
  313. my %channels = (
  314. 1 => 1,
  315. 2 => 1,
  316. 4 => 1,
  317. 5 => 1,
  318. 6 => 1,
  319. 7 => 1,
  320. 8 => 1,
  321. 9 => 1,
  322. 13 => 1,
  323. 14 => 1,
  324. 15 => 1,
  325. );
  326. # Random data for each channel
  327. my @data_set = ();
  328. foreach my $chan (keys(%channels)) {
  329. my $val = int(rand($max_val));
  330. my $dur = int(rand($max_dur));
  331. push(@data_set, { 'channel' => $chan, 'value' => $val, 'time' => $dur });
  332. }
  333. # Push the data set
  334. DMX::applyDataset(\@data_set, 'RAVE', $OUTPUT_FILE);
  335. $pushLast = time();
  336. # Wait just a bit, to prevent seizures
  337. usleep($max_dur * 1000);
  338. }